语法参考

// 显式类型定义
定义(整型) 数量 = 100;
定义(字符串) 消息 = "你好，世界！";
定义(小数) 温度 = 36.5;
定义(布尔型) 已完成 = 真;

// 先声明后赋值
定义(整型) 计数;
计数 = 0;

// 多变量定义
定义(整型) 宽度 = 800, 高度 = 600;

// 单条件判断
定义(整型) 分数 = 85;

如果 (分数 >= 90) {
    控制台输出("优秀");
} 否则如果 (分数 >= 80) {
    控制台输出("良好");
} 否则如果 (分数 >= 60) {
    控制台输出("及格");
} 否则 {
    控制台输出("不及格");
}

// 使用中文逻辑关键字
定义(整型) 年龄 = 25;
定义(布尔型) 有证件 = 真;

如果 (年龄 >= 18 并且 有证件) {
    控制台输出("可以进入");
} 否则 {
    控制台输出("禁止进入");
}

// 基础计数循环
对于 (定义(整型) i = 0; i < 10; i++) {
    控制台输出("当前值: " + i);
}

// 计算阶乘
定义(整型) 结果 = 1;
对于 (定义(整型) i = 1; i <= 10; i++) {
    结果 = 结果 * i;
}
控制台输出("10的阶乘: " + 结果);

// 循环控制
对于 (定义(整型) i = 0; i < 100; i++) {
    如果 (i == 5) {
        退出循环;  // 跳出循环
    }
    如果 (i % 2 == 0) {
        下一层循环;  // 跳过偶数
    }
    控制台输出(i);
}

// 条件循环
定义(整型) 计数 = 0;
当 (计数 < 5) {
    控制台输出("计数: " + 计数);
    计数++;
}

// 猜数字游戏
定义(整型) 目标 = 42;
定义(整型) 猜测 = 0;
当 (猜测 != 目标) {
    控制台输出("请猜一个数字:");
    猜测 = 控制台输入();
    如果 (猜测 < 目标) {
        控制台输出("太小了");
    } 否则如果 (猜测 > 目标) {
        控制台输出("太大了");
    }
}
控制台输出("恭喜你猜对了！");

// 无参数无返回值函数
定义(空类型) 打招呼() {
    控制台输出("你好，世界！");
}

// 带参数函数
定义(空类型) 问候(字符串 名字) {
    控制台输出("你好，" + 名字 + "！");
}

// 带返回值函数
定义(整型) 加法(整型 甲, 整型 乙) {
    返回 甲 + 乙;
}

// 递归函数
定义(整型) 阶乘(整型 数值) {
    如果 (数值 <= 1) {
        返回 1;
    }
    返回 数值 * 阶乘(数值 - 1);
}

// 主函数
定义(整型) 主函数() {
    打招呼();
    问候("张三");
    
    定义(整型) 结果 = 加法(10, 20);
    控制台输出("10 + 20 = " + 结果);
    
    控制台输出("5的阶乘 = " + 阶乘(5));
    
    返回 0;
}

// 定义结构体
结构体 学生信息 {
    字符串 姓名;
    整型 年龄;
    小数 分数;
    布尔型 是否毕业;
};

// 使用结构体
定义(学生信息) 学生一;
学生一.姓名 = "张三";
学生一.年龄 = 20;
学生一.分数 = 85.5;
学生一.是否毕业 = 假;

// 访问成员
控制台输出("姓名: " + 学生一.姓名);
控制台输出("年龄: " + 学生一.年龄);
控制台输出("分数: " + 学生一.分数);

// 一维数组
定义(整型) 数值列表[5];
数值列表[0] = 10;
数值列表[1] = 20;
数值列表[2] = 30;

// 遍历数组
对于 (定义(整型) i = 0; i < 5; i++) {
    控制台输出("数值列表[" + i + "] = " + 数值列表[i]);
}

// 二维数组
定义(整型) 矩阵[3][3];
对于 (定义(整型) i = 0; i < 3; i++) {
    对于 (定义(整型) j = 0; j < 3; j++) {
        矩阵[i][j] = i * 3 + j;
    }
}

// 导入标准库
导入("数学库");
导入("字符串库");
导入("文件库");

// 使用导入的函数
定义(小数) 结果 = 平方根(16);  // 4.0
定义(小数) 正弦值 = 正弦(3.14159 / 2);  // 1.0

// 字符串操作
定义(字符串) 文本 = "你好，世界！";
定义(整型) 长度 = 字符串长度(文本);

// 内联汇编 - 单行形式
asm("mov eax, 1");
asm("add eax, 2");

// 汇编执行 - 代码块形式
汇编执行 {
    mov eax, 10
    mov ebx, 20
    add eax, ebx
    // 结果存储在eax中
}

// 带变量替换的汇编
定义(整型) 数值 = 100;
汇编执行 {
    mov eax, ${数值}
    add eax, 50
    // eax = 150
}

// 获取汇编返回值
定义(整型) 结果;
汇编执行 {
    mov eax, 42
} -> 结果;
控制台输出("结果: " + 结果);  // 输出: 42

// 平台检测
控制台输出("当前平台: " + 平台);
控制台输出("操作系统: " + 操作系统);

// Windows API调用
如果 (平台 == "Windows") {
    定义(整型) 进程ID;
    WindowsAPI(24 进程ID);  // GetCurrentProcessId
    控制台输出("进程ID: " + 进程ID);
    
    定义(整型) 运行时间;
    WindowsAPI(0 运行时间);  // GetTickCount
    控制台输出("系统运行时间: " + 运行时间 + " 毫秒");
}

// Linux系统调用
如果 (平台 == "Linux") {
    定义(整型) 进程ID;
    系统调用(39 进程ID);  // getpid
    控制台输出("进程ID: " + 进程ID);
}

// 带参数的系统调用
定义(整型) 结果;
系统调用(调用号 结果 参数1 参数2 参数3);

// 显示平台信息
控制台输出("当前平台: " + 平台);
控制台输出("操作系统: " + 操作系统);

// 根据平台执行不同代码
如果 (平台 == "Windows") {
    控制台输出("运行在Windows系统");
} 否则如果 (平台 == "Linux") {
    控制台输出("运行在Linux系统");
} 否则如果 (平台 == "macOS") {
    控制台输出("运行在macOS系统");
} 否则如果 (平台 == "Android") {
    控制台输出("运行在Android系统");
} 否则 {
    控制台输出("未知平台");
}